循环保存并关闭每封打开的电子邮件，留下一封打开的邮件

Question

我经常打开许多窗口，关闭 Outlook 变得乏味。

我已经编写了这个 QuickClose 程序的两个版本，它们倾向于让电子邮件保持打开状态。

这个抛出一个索引数组越界错误：

Sub QuickClose()

Dim Inspector As Outlook.Inspector
Dim InspectorCount, i As Integer
Dim myItem As Object
'On Error Resume Next
If Application.Inspectors.count > 0 Then
    InspectorCount = Application.Inspectors.count

    For i = 1 To InspectorCount
        Set myItem = Application.Inspectors.Item(i)

        myItem.Activate

        If TypeName(myItem) = "Message" Then

            myItem.Close olSave

        End If

        If TypeOf ActiveInspector.CurrentItem Is MailItem Then

            ActiveInspector.CurrentItem.Close olSave

        End If

    Next i

End If

End Sub

这封邮件没有错误，但它也倾向于让一封电子邮件处于打开状态（而不是保存）：

Sub QuickClose1()

Dim Inspector As Outlook.Inspector
Dim InspectorCount As Integer
Dim myItem As Object

If Application.Inspectors.count > 0 Then

    For Each Inspector In Application.Inspectors
        Inspector.Activate
        Inspector.CurrentItem.Close olSave
    Next Inspector

End If
End Sub

一旦我让这部分工作，它将继续关闭 Outlook。

Answer 1

无需从活动的检查器窗口中获取项目。您可以使用 Inspector.Close 方法关闭 Inspector 并选择保存对显示的 Outlook 项目的更改。

Sub QuickClose()

Dim inspectors As Outlook.inspectors
Dim inspector As Outlook.inspector

Set inspectors = Application.inspectors

Do While inspectors.Count > 0
  Set inspector = inspectors.Item(1)
  inspector.Close olSave
Loop

End Sub