枚举计算机上设置的 DSN 列表答案

【问题标题】：Enumerating the list of DSN's set up on a computer枚举计算机上设置的 DSN 列表
【发布时间】：2018-05-30 03:03:45
【问题描述】：

我有一个 Excel 应用程序，我想在其中向用户显示数据源名称（即：DSN）的列表，以便她/他可以选择要使用的数据源。

希望获得列表后，我可以轻松访问 DSN 属性以连接到相应的数据库。

请注意，我确实不想使用无 DSN 连接。

【问题讨论】：

标签： vba excel dsn

【解决方案1】：

DSN 条目存储在注册表中的以下键中。

HKEY_CURRENT_USER\Software\ODBC\ODBC.INI\ODBC 数据源
HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBC.INI\ODBC 数据源

这包含所有已定义 DSN 的列表。这充当全局索引，每个 DSN 的特定详细信息存储在具有 DSN 名称的键中：

HKEY_CURRENT_USER\Software\ODBC\ODBC.INI
HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBC.INI

从数据源 (ODBC) 控制面板小程序的用户 DSN 和系统 DSN 选项卡中创建一些条目，并检查这些值是如何存储在注册表中的。

以下示例通过控制面板 > 管理工具 > 数据源 (ODBC) [用户 Dsn 选项卡] 枚举为用户定义的 DSN。

http://support.microsoft.com/kb/178755

  Option Explicit

  Private Declare Function RegOpenKeyEx Lib "advapi32.dll" _
      Alias "RegOpenKeyExA" _
      (ByVal hKey As Long, _
      ByVal lpSubKey As String, _
      ByVal ulOptions As Long, _
      ByVal samDesired As Long, phkResult As Long) As Long

  Private Declare Function RegEnumValue Lib "advapi32.dll" _
      Alias "RegEnumValueA" _
      (ByVal hKey As Long, _
      ByVal dwIndex As Long, _
      ByVal lpValueName As String, _
      lpcbValueName As Long, _
      ByVal lpReserved As Long, _
      lpType As Long, _
      lpData As Any, _
      lpcbData As Long) As Long

  Private Declare Function RegCloseKey Lib "advapi32.dll" _
      (ByVal hKey As Long) As Long

  Const HKEY_CLASSES_ROOT = &H80000000
  Const HKEY_CURRENT_USER = &H80000001
  Const HKEY_LOCAL_MACHINE = &H80000002
  Const HKEY_USERS = &H80000003

  Const ERROR_SUCCESS = 0&

  Const SYNCHRONIZE = &H100000
  Const STANDARD_RIGHTS_READ = &H20000
  Const STANDARD_RIGHTS_WRITE = &H20000
  Const STANDARD_RIGHTS_EXECUTE = &H20000
  Const STANDARD_RIGHTS_REQUIRED = &HF0000
  Const STANDARD_RIGHTS_ALL = &H1F0000
  Const KEY_QUERY_VALUE = &H1
  Const KEY_SET_VALUE = &H2
  Const KEY_CREATE_SUB_KEY = &H4
  Const KEY_ENUMERATE_SUB_KEYS = &H8
  Const KEY_NOTIFY = &H10
  Const KEY_CREATE_LINK = &H20
  Const KEY_READ = ((STANDARD_RIGHTS_READ Or _
                    KEY_QUERY_VALUE Or _
                    KEY_ENUMERATE_SUB_KEYS Or _
                    KEY_NOTIFY) And _
                    (Not SYNCHRONIZE))

  Const REG_DWORD = 4
  Const REG_BINARY = 3
  Const REG_SZ = 1

  Private Sub Command1_Click()
     Dim lngKeyHandle As Long
     Dim lngResult As Long
     Dim lngCurIdx As Long
     Dim strValue As String
     Dim lngValueLen As Long
     Dim lngData As Long
     Dim lngDataLen As Long
     Dim strResult As String

     lngResult = RegOpenKeyEx(HKEY_CURRENT_USER, _
             "SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources", _
              0&, _
              KEY_READ, _
              lngKeyHandle)

     If lngResult <> ERROR_SUCCESS Then
         MsgBox "Cannot open key"
         Exit Sub
     End If

     lngCurIdx = 0
     Do
        lngValueLen = 2000
        strValue = String(lngValueLen, 0)
        lngDataLen = 2000

        lngResult = RegEnumValue(lngKeyHandle, _
                                 lngCurIdx, _
                                 ByVal strValue, _
                                 lngValueLen, _
                                 0&, _
                                 REG_DWORD, _
                                 ByVal lngData, _
                                 lngDataLen)
        lngCurIdx = lngCurIdx + 1

        If lngResult = ERROR_SUCCESS Then
           strResult = strResult & lngCurIdx & ": " & Left(strValue, lngValueLen) & vbCrLf
        End If
     Loop While lngResult = ERROR_SUCCESS
     Call RegCloseKey(lngKeyHandle)

     Call MsgBox(strResult, vbInformation)
  End Sub

【讨论】：

绝妙的答案！它包括背景信息、参考链接和示例代码（效果很好！）。正是我希望 SO 会起作用的方式。非常感谢！

【解决方案2】：

您可以使用 ODBC API 的 SQLDataSources 函数。见MSDN documentation。

【讨论】：

【解决方案3】：

非常酷的解决方案。我遇到了一个问题，即 CURRENT_USER 没有显示所有 DSN，当然不是我需要的。我将其更改为 LOCAL_MACHINE 并看到了连接管理器中显示的所有 DSN，包括显示在 CURRENT_USER 下的子集。

http://msdn.microsoft.com/en-us/library/windows/desktop/ms712603(v=vs.85).aspx

【讨论】：