Document_Open() 在其他文件中不起作用

Question

我正在编写一个包含 1 个模块 (m1) 和 1 个用户表单 (uf) 的 VBA 项目。 在“ThisDocument”中，我从“m1”调用了一个公共子，它初始化了一个集合，然后我在用户表单中引用。在我将此项目部署到其他文件之前，这工作得很好。

我将文件作为 .dotm 保存在 %Appdata%/Microsoft/word/startup 文件夹中，这样我就可以在我的所有 word 文件中使用该项目。但是一旦我尝试在其他文件中使用我的项目，用户表单就会按设计自行打开，但集合是空的。

这可能是什么问题？

从用户窗体手动调用初始化方法可以正常工作。

'----------------------------------------------ThisDocument
Private Sub Document_Open()
    initBetaCollection
End Sub

'----------------------------------------------m1
Option Explicit

Public beta As Collection

Sub initBetaCollection()

    Set beta = New Collection

    beta.Add Array("0041", "A"), Key:="0041"
    '...

End Sub

'----------------------------------------------uf
Option Explicit
Private Sub txtSearch_Change()
    Dim arr As Variant
    Dim search As String

    'Defining the textinput as "search"
    search = txtSearch.Value

    For Each arr In beta
        If search <> "" Then 'No empty search field
            If arr(1) Like "*" & search & "*" Then 'Match found
                lbResults.AddItem arr(0)
            End If
        End If
    Next

End Sub

我得到：需要运行时错误“424”对象

Answer 1

在ThisDocument 类中使用Document_Open 或在常规模块中使用名为AutoOpen 的宏的问题在于，它们都专门为此文档（或从模板创建的文档）执行，仅 em>。

为了让所有打开的文档都触发一个应用程序级事件，有必要使用应用程序级事件。

为此，首先需要一个类模块。在类模块中，需要如下代码：

'Class module named: Class1
Public WithEvents app As Word.Application

Private Sub app_DocumentOpen(ByVal Doc As Document)
    'MsgBox Doc.FullName & ": on Open"
    'Code here that should fire when a document is opened
    'If something needs to be done with this document, use 
    'the Doc parameter passed to the event, don't try to use ActiveDocument
End Sub

然后，在常规模块中，可以使用AutoExec 宏来初始化具有事件处理的类。 （AutoExec：在 Word 启动并加载具有此名称的宏的模板时触发。）

Option Explicit

Dim theApp As New Class1

Sub AutoExec()
    'MsgBox "AutoExec"
    Set theApp.app = Word.Application        
End Sub

'Sub AutoOpen()
'    MsgBox "Open in AutoOpen" - fires only for this document
'End Sub