从 Excel VBA 宏运行 bat 文件，然后仅在 bat 文件执行后才执行附加代码

Question

我通常不在 VBA 中编写代码，但需要创建一个 VBA 宏，我可以从中运行一个执行 python 脚本的 .bat 文件。我已经能够做到这一点，但是由于程序在 excel 环境之外运行，我需要确定 .bat 文件何时完成，并向 excel 环境返回一条消息。 这是我目前所拥有的：

Shell ("CMD.EXE /c c:\IndexTrader\run_file\index_trader.bat")

一旦上述 .bat 文件运行，我如何才能在 excel 环境中打印一条消息，表明 .bat 文件已执行。 如果我在 .bat 文件命令之后运行顺序代码（参见上面的代码），由于 .bat 文件是在 excel 环境之外执行的，因此即使 .bat 文件尚未完成，在此命令之后运行的任何顺序代码也会运行。 有没有办法输出一条消息或参数表明.bat文件已执行，然后只执行VBA中的任何顺序代码。

Answer 1

完全披露：改编自Return result from Python to Vba 它本身受到Capture output value from a shell command in VBA?的影响

顺便说一句，如果您只想从 VBA 执行 python 脚本，那么请转到here。

基本上你需要创建一个WshShell 对象并调用它的WshShell.Exec。这将为您提供运行批处理文件的进程的句柄，甚至可以用于从 stdOut、stdErr 等中提取数据。

您需要的 VBA 代码是：

Public Function runProcess(cmd As String) As String

    Dim oShell As Object
    Dim oExec As Object, oOutput As Object
    Dim s As String, sLine As String

    Set oShell = VBA.CreateObject("Wscript.Shell")    

    Set oExec = oShell.Exec(cmd)
    Set oOutput = oExec.StdOut

    While Not oOutput.AtEndOfStream
        sLine = oOutput.ReadLine
        If sLine <> "" Then s = s & sLine & vbNewLine
    Wend

    Set oOutput = Nothing: Set oExec = Nothing
    Set oShell = Nothing

    runProcess = s

End Function

您可以像在您的示例中那样调用它，方法是：

Dim out_str As String
out_str = runProcess("c:\IndexTrader\run_file\index_trader.bat")
MsgBox "Script complete!"

您使用此方法获得的额外好处是您可以捕获该进程输出，从而将消息从您的 python 脚本传递回 VBA/Excel。

即使忽略返回值，在时间控制返回调用函数时也可以保证过程完成。

如果你是.bat 文件，你可以使用命令行参数：

Dim out_str As String
Dim arg1 As String
arg1 = "6"
out_str = runProcess("c:\IndexTrader\run_file\index_trader.bat " & arg1)
MsgBox "Script complete!"