如果两个单元格连续匹配，则需要给出一个名称，下一行匹配需要在 excel vba 中动态给出另一个名称

Question

我对编写 excel vba 代码有点困惑。请帮帮我。 这是我的要求

如果两个单元格连续匹配，则需要给出一个名称，下一行匹配需要通过excel vba中的循环动态地给出另一个名称

如果单元格-A = 1 和单元格-B = 2 则再次输入第一个名称，如果下一行是第二个名称

我的代码是

Sub fill_name()
    Dim i As Integer
    Dim nm As String
    Dim j As Integer
    Dim f_name() As String

    For i = 1 To 4

        ReDim f_name(2)
        For j = 1 To 2
            f_name(j) = Cells(j, 12).Value

            If Cells(i, 1).Value = "1" And Cells(i, 3).Value = "2" Then
                Cells(i, 2).Value = f_name(j)
            End If

        Next j
    Next i

End Sub

Answer 1

您不需要 VBA。您可以通过公式来实现这一点

把这个公式放到B2里拉下来

=IF(AND(A2=1,C2=2),IF(COUNTIF($B$1:$B1,"Hi")=COUNTIF($B$1:$B1,"Hello"),"Hi","Hello"),"")

如果您仍想使用 VBA，请像这样使用上面的公式

Sub fill_name()
    Dim ws As Worksheet
    Dim lRow As Long
    Dim sFormula As String

    sFormula = "=IF(AND(A2=1,C2=2),IF(COUNTIF(" & _
               "$B$1:$B1,""Hi"")=COUNTIF($B$1:$B1,""Hello"")" & _
               ",""Hi"",""Hello""),"""")"

    '~~> Change this as per your requirement
    Set ws = ThisWorkbook.Sheets("Sheet1")

    With ws
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row

        With .Range("B2:B" & lRow)
            .Formula = sFormula
            .Value = .Value
        End With
    End With
End Sub

如果你不想使用公式但想循环，那么像这样使用它

Sub fill_name()
    Dim ws As Worksheet
    Dim lRow As Long
    Dim i As Long, j As Long
    Dim MyAr(1 To 2) As String

    MyAr(1) = "Hi"
    MyAr(2) = "Hello"
    j = 1

    '~~> Change this as per your requirement
    Set ws = ThisWorkbook.Sheets("Sheet1")

    With ws
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row

        For i = 1 To lRow
            If .Range("A" & i).Value = 1 And .Range("C" & i).Value = 2 Then
                .Range("B" & i).Value = MyAr(j)
                If j = 1 Then j = 2 Else j = 1
            End If
        Next i
    End With
End Sub