【问题标题】:All properties of Application.ActiveSheet in Excel - Object Browser does not list the properties of MembersExcel 中 Application.ActiveSheet 的所有属性 - 对象浏览器不列出成员的属性
【发布时间】:2020-09-22 22:44:43
【问题描述】:

Microsoft Docs 没有列出 Object Application.ActiveSheet 的所有属性: https://docs.microsoft.com/en-us/office/vba/api/excel.application.activesheet

它只包含一些属性,例如:ActiveSheet.Name。但是从我在网上找到的VBA脚本中,我知道还有更多的属性比如:ActiveSheet.Type

所以我想也许我可以用这个 VBA 代码列出它们:来自:VBA collection: list of keys

Sub AktivSheet()
Dim key As Variant
For Each key In Application.ActiveSheet
    Debug.Print "Key: " & key, "Value: " & Application.ActiveSheet.Item(key)
Next
End Sub

但它不起作用,Microsoft Docs 建议使用对象浏览器。但是对象浏览器没有列出 Application.ActiveSheet 的属性:

我没有想法!我只想要一个所有 ActiveSheet 属性的列表。因为我只需要知道活动工作表的文本方向,就好像它是从左到右或从右到左一样。

【问题讨论】:

  • Activesheet 返回Object,而不是特定类型,因为它可能不是工作表。如果您想知道 Worksheet 的属性,请在对象浏览器中查找 that。
  • 非常感谢@Rory Worksheet.DisplayRightToLeft 是我所需要的。现在我可以简单地使用ActiveSheet.DisplayRightToLeft,请写一个答案。 ActiveSheet 和 WorkSeet 也是对象吗?但正如你所说,它可能不是工作表,我明白了:D

标签: excel vba object objectbrowser


【解决方案1】:

我只想要一个所有 ActiveSheet 属性的列表

您无法使用 100% VBA 代码以编程方式轻松实现这一点,VBA 的反射功能几乎为零。

现在,假设我们不在寻找检索对象属性的编程方式,以下是如何使用对象浏览器来获取您要查找的内容。

首先,右键单击对象浏览器中的任意位置并选择“显示隐藏的成员”选项以显示您正在查看的所有库。这会在编辑代码时影响名称列表下拉列表:您现在会看到隐藏的成员。

Excel类型库中的一个隐藏模块,是一个名为Global的模块,带有一个隐藏的_Global接口:

隐藏的全局模块是您输入MsgBox ActiveSheet.Name 的方式,它“正常工作”(假设是一个ActiveSheet - 当没有活动的工作簿时,它总是会出现错误91在您正在使用的Application 实例中打开)即使您没有指定您正在使用的Workbook:隐含地,ActiveSheet 只是在处理ActiveWorkbook 的任何内容。

所以ActiveSheet 是一个属性,而不是一个对象。它是一个返回对象的属性,但它的声明类型是Object。

这意味着您直接针对ActiveSheet 进行的任何成员调用都是隐式后期绑定的:您可以输入MsgBox ActiveSheet.Naem,VBA 会很高兴地编译错字(Option Explicit 无法在此处保存您),并且只会吹在运行时出现错误 438“我找不到该属性!”。

为了知道ActiveSheet 有哪些属性,我们需要知道我们正在查看的run-time 类型。由于Workbook 对象中的工作表可以是Worksheet、Chart 或其他几种类型的遗留“工作表”对象,因此在编译时确实没有可访问的成员,因为在编译时ActiveSheet 只是一个指向 Object 的指针,它是什么类型的对象只有在运行时才能知道。

因此,我们不是针对ActiveSheet 进行编码,而是针对Worksheet 进行编码,因为我们知道我们期望使用的特定工作表是一个Worksheet 对象。

Dim Sheet As Worksheet
Set Sheet = ActiveSheet

现在,当我们键入 Sheet. 时,我们处于早期绑定状态(所涉及的类型在编译时是已知的并已解决),并且提供了所有可用成员的列表,这很有帮助:

每次访问返回Object 或Variant 的成员(函数、属性)时,对其进行的任何成员调用都将被后期绑定。

努力保持在早期绑定领域:根据需要声明局部变量,以便编译器能够“看到”并验证所有内容!尝试键入下面的代码以感受不同之处 - 每当您键入 . 点但没有出现任何内容时,这表明编译器正在忽略正在发生的事情并且您可能会将编译时错误转移到运行时:

MsgBox ActiveSheet.DisplayRightToLeft '<~ late bound
Dim Sheet As Worksheet
Set Sheet = ActiveSheet
MsgBox Sheet.DisplayRightToLeft '<~ early bound

【讨论】:

    猜你喜欢
    • 2013-12-16
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2020-10-14
    • 2011-03-29
    • 1970-01-01
    • 2015-07-21
    相关资源
    最近更新 更多