在 VBA 中循环多个范围时确定值

Question

我正在研究基于动态数据集设置图表最大值和最小值的宏。当用户选择他们的组时，图表会更新，并且宏会运行以将图表最大值和最小值更新到适当的比例。

我希望有人可以帮助我，因为我尝试使用 3 个范围内的变量来：

1. 根据范围内的单元格值选择图表
2. 根据范围内的单元格值设置最小值
3. 根据范围内的单元格值设置最大值

此时我可以提取图表名称，但无法从范围中获取最小值和最大值。

任何帮助将不胜感激！

Sub rescale()

ActiveSheet.Calculate

Dim ChrtNmRng As Range
Dim ChrtMinRng As Range
Dim ChrtMaxRng As Range
Dim cell As Range

Set ChrtNmRng = Sheets("Data").Range("o5:o20")
Set ChrtMinRng = Sheets("Data").Range("z5:z20")
Set ChrtMaxRng = Sheets("Data").Range("Aa5:Aa20")

For Each cell In ChrtNmRng

With Sheets("Dashboard").ChartObjects(cell.Value).Chart.Axes(xlValue)
    .MinimumScale = ChrtMinRng.Value
    .MaximumScale = ChrtMaxRng.Value
End With

Next cell

End Sub

Answer 1

这样做：

Sub rescale()
    Dim ChrtNmRng As Range, cell As Range

    ActiveSheet.Calculate
    Set ChrtNmRng = Sheets("Data").Range("o5:o20")

    For Each cell In ChrtNmRng
        With Sheets("Dashboard").ChartObjects(cell.Value).Chart.Axes(xlValue)
            .MinimumScale = Range("Z" & cell.Row)
            .MaximumScale = Range("AA" & cell.Row)
        End With
     Next cell  
End Sub

这里的关键是您的最小值和最大值范围（Z 和 AA）与列 O 精确对齐，因此您可以使用 row 引用来获取所需的相应值。

Answer 2

据我了解，您的 cmets。 O 列包含图表的名称，其他列包含所需的每个图表的最小值和最大值。

Sub rescale()

ActiveSheet.Calculate

Dim ChrtNmRng As Range
Dim ChrtMinRng As Range
Dim ChrtMaxRng As Range
Dim i As Long

Set ChrtNmRng = Sheets("Data").Range("o5:o20")
Set ChrtMinRng = Sheets("Data").Range("z5:z20")
Set ChrtMaxRng = Sheets("Data").Range("Aa5:Aa20")

For i = 1 To 16

With Sheets("Dashboard").ChartObjects(ChrtNmRng(i).Value).Chart.Axes(xlValue)
    .MinimumScale = ChrtMinRng(i).Value
    .MaximumScale = ChrtMaxRng(i).Value
End With

Next i

End Sub