从一个工作簿到另一个工作簿查找匹配的值行 ID

Question

我有两个 Excel Book1.xlsm 和 Book2.xlsx。 Book1 将在 A 列中具有某些值，如 alpha、beta、gamma 等（无重复）。 Book2 将多次出现 Book1 值，如 beta、beta、beta、alpha、alpha、gamma、gamma、gamma、gamma、gamma等 Book2 中的值可能不会按字母顺序排序，但相同的值将组合在一起。 Book2 的值也将在 A 列中。

我在 Book1.xlsm 中设计了一个宏，它应该遍历 Book1 列 A 中的每个值，并找到 Book2 列 A 中存在相同值的第一行 id。然后应该将该行 id 复制到对应的列 B 中书 1。 这就是我的宏代码的样子。当我运行时，它会因运行时错误“1004”而失败：应用程序定义或对象定义错误

Option Explicit
Sub Get_Data()
    Dim wb1 As Worksheet
    Dim wb2 As Worksheet
    Dim wb2row As Integer
    Dim i As Integer
    Dim j As Integer
    Const A = "A"
    Const B = "B"



    Set wb1 = Workbooks("Book1.xlsm").Worksheets("Sheet1")
    Set wb2 = Workbooks("Book2.xlsx").Worksheets("Sheet1")

      'Both For loop start from row id 2.
       For i = 2 To wb1.Range("A2", wb1.Range("A2").End(xlDown)).Rows.Count
        For j = 2 To wb2.Range("A2", wb2.Range("A2").End(xlDown)).Rows.Count
  
           wb2row = Application.WorksheetFunction.Match(wb1.Cells(i, A), Range(wb2.Cells(j, A)), 0)
                    wb1.Cells(i, B).Copy (wb2.Cells(j, A))
       
            Exit For ' j loop

    
        Next j
     Next i

End Sub

Answer 1

您可以让 excel 为您完成工作。试试这个（已测试）

Sub Get_Data()
  With Workbooks("Book1.xlsm").Sheets("Sheet1")
    With .Range(.Range("B2"), .Range("A" & Rows.Count).End(xlUp).Offset(0, 1))
      .Formula2 = "=IFERROR(MATCH(A2,[Book2.xlsx]Sheet1!$A:$A,0),"""")"
      .Value2 = .Value2
    End With
  End With
End Sub

Answer 2

匹配条件，返回行

Option Explicit

Sub Get_Data()
    
    ' Source
    Const srcFirst As Long = 2
    Const srcCol As String = "A"
    ' Destination
    Const dstFirst As Long = 2
    Const dstCol As String = "A"
    Const resCol As String = "B"

    ' Source
    Dim src As Worksheet
    Set src = Workbooks("Book2.xlsx").Worksheets("Sheet1")
    Dim rng As Range
    Set rng = src.Range(src.Cells(srcFirst, srcCol), _
        src.Cells(src.Rows.Count, srcCol).End(xlUp))
    Dim RowOffset As Long
    RowOffset = srcFirst - 1
    ' Destination
    ' 'ThisWorkbook' - the workbook containing this code.
    Dim dst As Worksheet
    Set dst = ThisWorkbook.Worksheets("Sheet1")
    
    Dim srcRow As Variant ' It could be an error value, hence 'Variant'.
    Dim i As Long
    
    For i = 2 To dst.Cells(dst.Rows.Count, dstCol).End(xlUp).Row
        srcRow = Application.Match(dst.Cells(i, dstCol), rng, 0)
        If Not IsError(srcRow) Then
            ' This will write the row.
            ' If you need index, then remove 'RowOffset'.
            dst.Cells(i, resCol).Value = srcRow + RowOffset
        Else
        ' no match found, e.g.:
            'dst.Cells(i, resCol).Value = ""
        End If
    Next i

End Sub

Answer 3

match函数的第二个参数必须是一个范围，而不是单个单元格。