在 Excel Visual Basic 中从 CSV 中删除连续的重复值

Question

在 Excel 2007 VB 宏中，我尝试使用逗号分隔的字符串，将其拆分，然后对其进行缩减，从而删除重复的连续值。所以“2,2,2,1,1”会变成“2,1”，或者“3,3,3,2,3,3,3”会变成“3,2,3”。

看起来它应该可以工作，但是当它到达“If currentVal.equals(prevVal) = False Then”时，它是一个运行时错误 424，“需要对象”。

自从我做任何 VB 以来，这已经是永远，那就是 VP6。

Sheets("Sheet1").Select
Range("I1").Select

Dim data() As String
Dim currentVal, prevVal As String
Dim output As String
Dim temp As Boolean

Do Until Selection.Value = ""
        data = Split(Selection, ",")
        output = ""
        prevVal = ""
        For Each elem In data
            currentVal = CStr(elem)
            If currentVal.equals(prevVal) = False Then
            output = output + elem + ","
            End If
        Next elem
        Selection.Value = output
        Selection.Offset(1, 0).Select
Loop

Answer 1

有一些问题。首先，你不能使用：

Dim currentVal, prevVal As String

你必须使用：

Dim currentVal as String
Dim prevVal As String

或：

Dim currentVal as String, prevVal as String

...不幸的是，您不能在 VBA 中使用快捷方式类型。其次，字符串不是 VBA 中的对象，因此没有 .equals （或任何其他方法）。你想要：

If currentVal <> prevVal Then

最后，您需要在循环结束时设置 prevVal，否则您的代码将无法按预期工作。

编辑这是一些工作代码：

Dim data() As String
Dim currentVal As String, prevVal As String
Dim output As String
Dim temp As Boolean

Do Until Selection.Value = ""
        data = Split(Selection, ",")
        output = ""
        prevVal = ""
        For Each elem In data
            currentVal = CStr(elem)
            If currentVal <> prevVal Then
                output = output + elem + ","
            End If
            prevVal = currentVal
        Next elem
        Selection.Value = output
        Selection.Offset(1, 0).Select
Loop

Answer 2

我建议使用带有正则表达式的变体数组，以最大限度地提高方法的效率和速度。像这样的

更新：根据我自己的建议，代码现在在应用变量数组之前测试超过 1 个单元格

   Sub Clear()
    Dim ws As Worksheet
    Dim rng1 As Range
    Dim X
    Dim lngRow As Long
    Dim objRegex
    Set objRegex = CreateObject("vbscript.regexp")
    Set ws = Sheets("Sheet1")
    Set rng1 = ws.Range(ws.[i1], ws.Cells(Rows.Count, "I").End(xlUp))
    With objRegex
        .Global = True
        .Pattern = "(\d)(,(\1))+"
        If rng1.Cells.Count > 1 Then
            X = rng1
            For lngRow = 1 To UBound(X)
                X(lngRow, 1) = .Replace(X(lngRow, 1), "$1")
            Next lngRow
            rng1 = X
        Else
            rng1.Value = .Replace(rng1.Value, "$1")
        End If
    End With
End Sub

Answer 3

您可以使用字典对象，尤其是因为您要将数字移动到文本文件中，因此它们本身不被视为数字并不重要。见this question