VBA宏将文档中的所有标题格式化为粗体

Question

我正在尝试自动搜索/替换 Word 2013 文档中的标题（请注意，这些不是 Word 样式的标题，而只是用冒号以大写字母键入的文本）。例如：

主要投诉：

体格检查：

搜索和替换只是将标题格式化为粗体，否则必须手动完成，否则标题文本保持不变。无法知道文档中将包含哪些标题（或是否有标题）、哪种顺序或文档的第一行是否包含标题。

手动搜索/替换：^13(*:)

对此：^p\1

有效，除非第一个实例位于文件的开头（不返回）。

我一直使用的宏是这样的：

Sub BoldHeadings()
'
' BoldHeadings Macro
'
Application.ScreenUpdating = False
With ActiveDocument.Range.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  .Format = False
  .Forward = True
  .MatchWildcards = True
  .Wrap = wdFindContinue
  .Text = "^13(*:)"
  .Replacement.Text = "^p\1"
  .Replacement.Font.Bold = True
  .Execute Replace:=wdReplaceAll
  .Replacement.ClearFormatting
End With
Application.ScreenUpdating = True
End Sub

如上所述，这可以正常工作，除非第一个实例位于文件的开头。还有其他方法可以实现吗？

谢谢！

Answer 1

试试：

Sub BoldHeadings()
Application.ScreenUpdating = False
With ActiveDocument.Range
  .InsertBefore vbCr
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Replacement.Font.Bold = True
    .Text = "^13*:"
    .Replacement.Text = "^&"
    .Format = True
    .Forward = True
    .MatchWildcards = True
    .Wrap = wdFindContinue
    .Execute Replace:=wdReplaceAll
  End With
  .Paragraphs.First.Range.Delete
End With
Application.ScreenUpdating = True
End Sub