从一个 ListObject 复制到另一个 VBA

Question

更多关于在这里编写漂亮的 VBA 代码的问题，因为它在技术上是有效的。我有一个简单的任务 - 我需要从一个 ListObject 复制数据（来自 4 列表的 2 列）并将其添加到另一个 2 列表的末尾（并让 Excel 表自动展开）。

我创建了 Range Trans_log，用于处理我需要复制的两列。我通过 newrow 定位新创建的 ListRow，以免意外地将数据粘贴到表格中间的某个位置。

但是有没有更简洁的方法来做到这一点，而不是使用 With、.Activate 和 ActiveCell ？

Sub Copy()

Dim newrow As ListRow
Set newrow = ActiveSheet.ListObjects("Log").ListRows.Add

ActiveSheet.Range("Trans_log").Copy

With newrow

.Range(1).Activate
ActiveCell.PasteSpecial xlPasteValues

End With

End Sub

Answer 1

您可以这样做 - 直接分配值而不是复制/粘贴

Sub Copy()

    Dim newrow As ListRow
    With ActiveSheet
        Set newrow = .ListObjects("Log").ListRows.Add()
        newrow.Range.Value = .Range("Trans_log").Value 
    End With
End Sub

EDIT：用于复制多行

Sub Copy()
    Dim rw As Range
    Dim newrow As ListRow
    Dim lst As ListObject, sht As Worksheet

    Set sht = Sheets(1)
    Set lst = sht.ListObjects("Log")

    'loop over rows in named range
    For Each rw In sht.Range("Trans_log").Rows
        'only copy rows with data
        If Application.CountA(rw) > 0 Then
            Set newrow = lst.ListRows.Add()
            newrow.Range.Value = rw.Value
        End If
    Next rw
End Sub