XSLT 1.0 将多次出现的 char 替换为 <br />

Question

有以下与 xsl:call-template 一起使用的模板，但我需要用它来将 ~ 替换为 <br />。我可以让它在没有 HTML 替换的情况下工作，但当我尝试使用 <br /> 或 
 或 
 时却不行。任何建议：

<xsl:template name="replace-substring">
<xsl:param name="original"/>
<xsl:param name="substring"/>
<xsl:param name="replacement" select="''"/>
<xsl:variable name="first">
    <xsl:choose>
        <xsl:when test="contains($original, $substring)" >
            <xsl:value-of select="substring-before($original, $substring)" />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$original"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:variable>
<xsl:variable name="middle">
    <xsl:choose>
        <xsl:when test="contains($original, $substring)">
            <xsl:value-of select="$replacement" />
        </xsl:when>
        <xsl:otherwise>
            <xsl:text></xsl:text>
        </xsl:otherwise>
    </xsl:choose>
</xsl:variable>
<xsl:variable name="last">
    <xsl:choose>
        <xsl:when test="contains($original, $substring)">
            <xsl:choose>
                <xsl:when test="contains(substring-after($original, $substring), 
                    $substring)">
                    <xsl:call-template name="replace-substring">
                        <xsl:with-param name="original">
                            <xsl:value-of select="substring-after($original, $substring)"/>
                        </xsl:with-param>
                        <xsl:with-param name="substring">
                            <xsl:value-of select="$substring"/>
                        </xsl:with-param>
                        <xsl:with-param name="replacement">
                            <xsl:value-of select="$replacement"/>
                        </xsl:with-param>
                    </xsl:call-template>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="substring-after($original, $substring)"  />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:when>
        <xsl:otherwise>
            <xsl:text></xsl:text>
        </xsl:otherwise>
    </xsl:choose>
</xsl:variable>
<xsl:value-of select="concat($first, $middle, $last)"/>
</xsl:template>

Answer 1

很难判断第一个、中间和最后一个变量发生了什么，但您应该能够在参数中只使用文字 <br/>...

XML

<test>one~two~three</test>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="test">
    <xsl:copy>
      <xsl:call-template name="replace-char"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template name="replace-char">
    <xsl:param name="char" select="'~'"/>
    <xsl:param name="replacement"><br/></xsl:param>
    <xsl:param name="string" select="."/>
    <xsl:variable name="remaining" select="substring-after($string,$char)"/>
    <xsl:value-of select="substring-before(concat($string,$char),$char)"/>
    <xsl:if test="contains($string,$char)">
      <xsl:copy-of select="$replacement"/>      
    </xsl:if>
    <xsl:if test="$remaining">
      <xsl:call-template name="replace-char">
        <xsl:with-param name="string" select="$remaining"/>
        <xsl:with-param name="char" select="$char"/>
        <xsl:with-param name="replacement" select="$replacement"/>
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

输出

<test>one<br/>two<br/>three</test>