条件公式中的共享点日期函数答案

【问题标题】：Sharepoint date function in conditional formula条件公式中的共享点日期函数
【发布时间】：2012-03-28 10:22:33
【问题描述】：

我想在（类型计算）[No. vacante] 列有“vacante 1”或“vacante 2”我的代码如下。我得到的错误是语法错误或公式不受支持，但我无法弄清楚错误在哪里。

=IF([No. vacante]="vacante 1",(DATE(YEAR([fecha ingreso]),MONTH([fecha ingreso]),DAY([fecha ingreso])+1)),
IF([No. vacante]="vacante 2",(DATE(YEAR([fecha ingreso]),MONTH([fecha ingreso]),DAY([fecha ingreso])+2) )),
IF([No. vacante]="vacante 3",(DATE(YEAR([fecha ingreso]),MONTH([fecha ingreso]),DAY([fecha ingreso])+3))))

【问题讨论】：

标签： sharepoint date conditional add formula

【解决方案1】：

提供的公式有两个问题：

第三个 IF 语句嵌套在错误的级别（在 IF #1 而不是 IF #2 内部）。
第三个 IF 语句还需要一个默认值作为其第三个参数，以便公式始终返回某个值。

Sharepoint 中的每个 IF 语句都需要三个值：要计算的表达式、true 的值和 false 的值。微软提供a more detailed explanation。

我相信下面的公式应该可以完成这项工作。如果[No. vacante] 不等于vacante 1、vacante 2 或vacante 3 中的任何一个，请确保将default_value_goes_here 替换为要使用的适当默认值。

=
    IF(
        [No. vacante]="vacante 1", 
        (DATE
            (YEAR([fecha ingreso]),
            MONTH([fecha ingreso]),
            DAY([fecha ingreso])+1)
        ),
        IF(
            [No. vacante]="vacante 2",
            (DATE
                (YEAR([fecha ingreso]),
                MONTH([fecha ingreso]),
                DAY([fecha ingreso])+2)
            ),
            IF(
                [No. vacante]="vacante 3",
                (DATE
                    (YEAR([fecha ingreso]),
                    MONTH([fecha ingreso]),
                    DAY([fecha ingreso])+3)
                ),
                default_value_goes_here
            )
        )
    )

【讨论】：