Excel - 使用当前日期在工作簿中选择单元格的宏

Question

我正在 Excel 中创建日历/计划工作簿。每个月都有一个工作表。

现在我需要创建一个CommandButton，它将我带到包含当前日期的单元格。当前日期只有一个单元格，但可以在工作簿的任何工作表上。

我已经找了好几天了，但还是找不到！

我一直在尝试的事情：

Private Sub CommandButton1_Click()

Dim Sh As Worksheet
Dim Loc As Range

For Each Sh In ThisWorkbook.Worksheets
    With Sh.UsedRange
        Set Loc = .Cells.Find(What:=Int(Date), LookIn:=xlValues)
        If Not Loc Is Nothing Then
            Do Until Loc Is Nothing
                Loc.Select
                Set Loc = .FindNext(Loc)
            Loop
        End If
    End With
    Set Loc = Nothing

Next

End Sub

当具有当前日期的单元格在同一张纸上时，这有点工作（尽管它会一直重新选择单元格，直到我按 Esc），但当单元格在另一张纸上时会失败。

任何帮助将不胜感激！

Answer 1

我认为您不需要 Do While 循环。由于您只是在寻找一个，因此这个简单的 For/Next 应该可以。一旦发现代码退出循环并转到最后的选择部分。如果未找到日期，则不选择任何内容：

Private Sub CommandButton1_Click()
Dim Sh As Worksheet
Dim Loc As Range

For Each Sh In ThisWorkbook.Worksheets
    With Sh.UsedRange
        Set Loc = .Cells.Find(What:=Int(Date), LookIn:=xlValues)
        If Not Loc Is Nothing Then
            Exit For
        End If
    End With
Next
If Not Loc Is Nothing Then
    'need to activate parent sheet before selecting cell
    Loc.Parent.Activate
    Loc.Select
End If
End Sub

请注意，在选择范围之前，您需要激活父工作表。