Gnuplot pm3d 地图：不同的 x2tics、y2tics

Question

我可以绘制一个“ploe figure”：

degtorad(x)=x/180*pi
radtodeg(x)=x/pi*180

set pm3d map
set pm3d interpolate 0,0
set logscale zcb

set palette model RGB rgbformulae 33,13,10

set size ratio 1

set xtics("{/Symbol b}=180{/Symbol \260}" 0)

set ytics("0" -90, "10" -80, "20" -70, "30" -60, "40" -50, "50" -40, "60" -30, "70" -20, "80" -10, "90" 0, "80" 10, "70" 20, "60" 30, "50" 40, "40" 50, "30" 60, "20" 70, "10" 80, "0" 90)

splot[-90:90][-90:90] 'TSC3.txt' u (radtodeg(cos(degtorad($1+90))*degtorad(90-$2))):(radtodeg(degtorad(90-$2)*sin(degtorad($1+90)))):3 notitle 

其中第 1 列包含“beta”，第 2 列包含“alpha”，但这并不重要。

问题是

1. 如何删除正确的ticmarks（unset y2tics不起作用）？
2. 如何在上侧设置“beta=0°”（set x2tics("{/Symbol b}=0{/Symbol \260}" 0) 不起作用）？

Answer 1

右侧和顶部边框上未标记的抽动与 x2 轴和 y2 轴无关。它们是 x 轴和 y 轴的镜像抽动。要关闭正确的抽动，请使用set ytics ... nomirror。

如果我没记错的话，在早期版本中，splot 根本不适用于 x2 和 y2 轴。至少在 5.2 中，您可以使用set link x2 将 x2 轴链接到与 x 轴相同的范围，然后您可以将 tic 放置在 x2 轴上：

degtorad(x)=x/180*pi
radtodeg(x)=x/pi*180

set pm3d map
set pm3d interpolate 0,0
set logscale zcb

set palette model RGB rgbformulae 33,13,10

set size ratio 1

set link x2
set x2tics ("{/Symbol b}=180{/Symbol \260}" 0)

set ytics nomirror ("0" -90, "10" -80, "20" -70, "30" -60, "40" -50, "50" -40, "60" -30, "70" -20, "80" -10, "90" 0, "80" 10, "70" 20, "60" 30, "50" 40, "40" 50, "30" 60, "20" 70, "10" 80, "0" 90)

splot[-90:90][-90:90] 'TSC3.txt' u (radtodeg(cos(degtorad($1+90))*degtorad(90-$2))):(radtodeg(degtorad(90-$2)*sin(degtorad($1+90)))):3 notitle