为什么我不能将 TObjectList<S: T> 传递给需要 TObjectList<T> 的函数？

Question

我的代码有问题，它使用泛型类型。为什么编译器不知道传递的列表（Result）是TObjectList<TItem>（TItem 是T in TItems 的类型）？

界面：

type
   TItem = class
end;

type
  IItemsLoader = interface
    procedure LoadAll(AList : TObjectList<TItem>);
end;

type
  TItemsLoader = class(TInterfacedObject, IItemsLoader)
public
  procedure LoadAll(AList : TObjectList<TItem>);
end;

type
  IItems<T : TItem> = interface
  function LoadAll : TObjectList<T>;
end;

type
  TItems<T : TItem> = class(TInterfacedObject, IItems<T>)
  private
    FItemsLoader : TItemsLoader;
  public
    constructor Create;
    destructor Destroy; override;
    function LoadAll : TObjectList<T>;
end;

实施：

procedure TItemsLoader.LoadAll(AList: TObjectList<TItem>);
begin
  /// some stuff with AList
end;

{ TItems<T> }

constructor TItems<T>.Create;
begin
  FItemsLoader := TItemsLoader.Create;
end;

destructor TItems<T>.Destroy;
begin
  FItemsLoader.Free;
  inherited;
end;

function TItems<T>.LoadAll: TObjectList<T>;
begin
  Result := TObjectList<T>.Create();

  /// Error here
  /// FItemsLoader.LoadAll(Result);
end;

Answer 1

您还必须使用通用版本的加载器：

type
   TItem = class
end;

type
  IItemsLoader<T: TItem> = interface
    procedure LoadAll(AList : TObjectList<T>);
end;

type
  TItemsLoader<T: TItem> = class(TInterfacedObject, IItemsLoader<T>)
public
  procedure LoadAll(AList : TObjectList<T>);
end;

type
  IItems<T : TItem> = interface
  function LoadAll : TObjectList<T>;
end;

type
  TItems<T : TItem> = class(TInterfacedObject, IItems<T>)
  private
    FItemsLoader : TItemsLoader<T>;
  public
    constructor Create;
    destructor Destroy; override;
    function LoadAll : TObjectList<T>;
end;


implementation

{$R *.dfm}

procedure TItemsLoader<T>.LoadAll(AList: TObjectList<T>);
begin
  /// some stuff with AList
end;

{ TItems<T> }

constructor TItems<T>.Create;
begin
  FItemsLoader := TItemsLoader<T>.Create;
end;

destructor TItems<T>.Destroy;
begin
  FItemsLoader.Free;
  inherited;
end;

function TItems<T>.LoadAll: TObjectList<T>;
begin
  Result := TObjectList<T>.Create();

  /// Error here
  FItemsLoader.LoadAll(Result);
end;

Answer 2

在有错误的函数中，Result 是一个TObjectList<T>，其中T 是TItem 的某个子类，但编译器不知道它是什么具体的类。编译器必须对其进行编译，以便对于T 的any 值可以安全运行。这可能与需要TObjectList<TItem> 的LoadAll 的参数类型不兼容，因此编译器会拒绝该代码。

假设T是TItemDescendant，编译器允许错误代码编译执行。如果LoadAll 调用AList.Add(TItem.Create)，那么AList 将最终持有不是TItemDescendant 的东西，即使它是TObjectList<TItemDescendant>。它所持有的对象的类型与其泛型类型参数所说的不同。

仅仅因为S 是T 的子类型并不意味着X<S> 是X<T> 的子类型。