在 Word VBA 中向书签添加多个表格，同时维护和扩展书签

Question

我正在尝试使用 Word VBA 创建一些自动化并寻求一些建议。

我在文档中有一个书签。我想要做的是调用一些 VBA，它会转到该书签并创建许多表，可能是 1，也可能是 50，具体取决于某些变量。

我想维护那个书签，使它覆盖整个新的表格部分，这样如果有人再次运行宏，表格就会被删除并很好地重新创建。

到目前为止，我有一些代码可以在书签处创建表格并重新创建它，但它似乎是在第一个单元格中创建书签作为表格嵌套。

谁能帮帮我？

Private Sub InsertTableInBookmark(BookmarkName As String)

Debug.Print "[INFO] Started Private Sub InsertTableInBookmark"

Dim objRng As Range
Dim objTable As Table

Selection.GoTo what:=wdGoToBookmark, Name:=BookmarkName
Selection.Expand wdParagraph

ActiveDocument.Tables.Add Range:=Selection.Range, NumRows:=9, NumColumns:=4, DefaultTableBehavior:=wdWord9TableBehavior
ActiveDocument.Bookmarks.Add BookmarkName, Selection.Range

Debug.Print "[INFO] Finished Private Sub InsertTableInBookmark"

End Sub

谢谢。

Answer 1

试试：

Private Sub InsertTableInBookmark(BmkNm As String, t As Long)
Dim i As Long, BmkRng As Range, Tbl As Table
With ActiveDocument
  If .Bookmarks.Exists(BmkNm) Then
    Set BmkRng = .Bookmarks(BmkNm).Range
    For i = 1 To t
      Set Tbl = .Tables.Add(Range:=BmkRng.Characters.Last, _
        NumRows:=9, NumColumns:=4, DefaultTableBehavior:=wdWord9TableBehavior)
      With BmkRng
        .End = Tbl.Range.End
        If i < t Then
          .Characters.Last.Next.InsertBefore vbCr & vbCr
          .End = .End + 2
        End If
      End With
    Next
    .Bookmarks.Add BmkNm, BmkRng
  End If
End With
Set BmkRng = Nothing
End Sub

请注意，我在 sub - t - 中添加了另一个参数，表示要插入的表数。