VBA：为word中的超链接添加样式

Question

我正在尝试制作一个宏来根据级别添加具有不同样式的超链接，每个链接在表格中的新行上。

1. hyperlinktext1 (sub style1) (即粗体和大小 16)

   1.1 hyperlinktext2 (sub style2) (即大小14)

我已确保样式存在并且适用于普通文本，但我无法将样式应用于使用 VBA 添加的超链接。

更改样式适用于我出于某种原因手动添加的超链接。

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
    "file.pdf", SubAddress:="", ScreenTip:="", TextToDisplay:="text1"
    Selection.Style = ActiveDocument.Styles("Sub level1")

    'new row
    Selection.MoveRight Unit:=wdCharacter, Count:=1
    Selection.InsertRows 1
    Selection.Collapse Direction:=wdCollapseStart

    ActiveDocument.Hyperlinks.Add Anchor:=Selection.Range, Address:= _
    "file2.pdf", SubAddress:="", ScreenTip:="", TextToDisplay:="text2"
    Selection.Style = ActiveDocument.Styles("Sub level2")

有什么建议吗？

Answer 1

当您插入超链接时，插入后的选择范围位于超链接的末尾。因此，在您的代码中，当您应用您的样式时，您将其应用到超链接末尾的插入点。

要获取超链接的范围，以便您可以对其应用样式，您可以移动选择范围的起点，或者更好的是，在插入超链接时捕获超链接。

在第一种情况下，您将添加该行

Selection.MoveStart unit:=wdWord, count:=-1

在 add 语句之后和应用样式的行之前。

执行任务的更好方法如下

Option explicit

Sub test()

    InsertHyperlinkWithStyle Selection.Range, "c:\path_to\file", ActiveDocument.Styles("Sub level1")

End Sub

Sub InsertHyperlinkWithStyle(this_range As Word.Range, this_file_path As String, this_style As Word.Style)

Dim my_hyperlink As Hyperlink

    Set my_hyperlink = ActiveDocument.Hyperlinks.Add( _
                        Anchor:=this_range.Duplicate, _
                        Address:=this_file_path, _
                        TextToDisplay:="text1")
    my_hyperlink.Range.Style = this_style

End Sub