Excel VBA application.visible 立即设置回 True

Question

我已经设置了一个新的、空的、无模式的用户表单，以用最少的代码解决我的问题。

当打开工作簿时，执行以下代码以隐藏 Excel 并显示用户窗体。这是工作簿的唯一代码。

Private Sub Workbook_Open()
    UserForm1.Show
    If Application.Windows.Count <> 1 Then
        Application.Windows("test.xlsm").Visible = False
    Else
        Application.Visible = False
    End If
End Sub

我有一个只有一个按钮的空用户表单。此用户表单的唯一代码是：

Private Sub CommandButton1_Click()
    Application.Windows("test.xlsm").Visible = True
    Application.Visible = True
Unload Me
End Sub

最后一件事是第一个工作表上的按钮，用于启动与打开工作簿时相同的过程。其代码：

Sub Button1_Click()
    UserForm1.Show
    If Application.Windows.Count <> 1 Then
        Application.Windows("test.xlsm").Visible = False
    Else
        Application.Visible = False
    End If
End Sub

现在我的问题： 当我打开工作簿时，会显示用户窗体，但 Excel 和活动窗口也保持可见。但是，如果我单击工作表上的按钮，Excel 或窗口将按应有的方式隐藏。此外，加载所有内容后，Excel（而不是用户表单）具有焦点。

我第一次运行它时，它运行良好。我怀疑更改编辑器中的 ShowModal 设置会以某种方式搞砸，但这只是我的猜测。无论如何，无论现在的模态设置如何，它都不再按预期工作了。

如果我只是跑步

Application.Visible = False

除了“if”子句，Excel 仍然保持可见，当然活动窗口也是如此。

这让我发疯了。 我错过了什么？

编辑：链接到我的测试文件：Test File on my Dropbox 可能必须启动它两次，因为当宏在启动时被阻止并且仅在 excel 完全加载后才激活时，代码会按预期工作。

编辑：我能够在 excel 2010 电脑上对此进行测试，但问题不存在。因此，这可能与较新的 Office Apps 处理内容的方式有关。

Answer 1

我发现自己遇到了完全相同的问题 - 使用 Workbook_Open() 事件打开的无模式表单也应该隐藏 excel 应用程序（在 Excel 2016 上工作，32 位）。

它使用 UserForm 属性 ShowModal 设置为 True 的原因是：the execution is suspended - it's waiting for user to interact with the UserForm that was shown.

如果我们将 ShowModal 更改为 False（或调用 UserForm.Show vbModeless），那么执行将永远不会暂停，并且一旦我们到达 End Sub 的 End Sub，Excel似乎自己设置了Application.Visible = True。

到目前为止，我发现的唯一解决方案是 this one - 基本上，您通过添加无限循环暂停执行，因此 Excel 只有在您摆脱 (Unload/隐藏）之前显示的表单。

我的版本是这样的：

Private Sub Workbook_Open()
    Dim App As Object
    Set App = startMenu

    App.Show vbModeless

    While App.Visible
        DoEvents
    Wend
End Sub

然后，为了确保在关闭无模式 UserForm 后关闭 Excel，我添加了以下内容：

Private Sub UserForm_Terminate()
    CloseApp
End Sub

Public Sub CloseApp()
    ThisWorkbook.Saved = True

    If Not OtherWorkbooksOpen Then
        Application.Quit
    Else
        ThisWorkbook.Close
    End If
End Sub

Public Function OtherWorkbooksOpen()
    If Application.Workbooks.Count > 1 Then
        OtherWorkbooksOpen = True
    Else
        OtherWorkbooksOpen = False
    End If
End Function

编辑：

Solution without infinite loop - Excel 的计划隐藏：

Private Sub Workbook_Open()
    Dim App As Object
    Set App = startMenu

    App.Show
    If Not OtherWorkbooksOpen Then
        Application.OnTime Now + TimeValue("00:00:01"), "HideExcel"
    End If
End Sub

Answer 2

我认为userform1.show需要在if语句执行后调用。

 Private Sub Workbook_Open()
    If Application.Windows.Count <> 1 Then
        Application.Windows("test.xlsm").Visible = False
    Else
        Application.Visible = False
    End If
    UserForm1.Show
End Sub

Answer 3

不是答案，但我不能将此作为评论发布。这对我有用 - 用户表单出现，应用程序被隐藏。我使用“2”，因为我有一个个人工作簿。你能确认你会发生什么吗？

 Private Sub Workbook_Open()
    If Application.Windows.Count <> 2 Then
        Application.Windows("test.xlsm").Visible = False
    Else
        Application.Visible = False
    End If
    UserForm1.Show False
End Sub

Answer 4

我遇到了同样的问题，但我注意到表单在 excel 文件之前加载。所以我在表单中添加了一个调用 application.visible = false 的冗余。 基本上在单击表单中的任何内容后，它将调用 application.visible = false 并且 excel 窗口将隐藏。