循环并存储玩家姓名提示，直到满足 X 数量

Question

我有十个案例陈述，每一个都是基于玩家数量的。游戏 1、3 和 5 是单人游戏。游戏 2、4 和 6 是两人游戏，游戏 7、8、9 和 10 是四人游戏。

我试图弄清楚如何使用循环来提示用户选择游戏的相应玩家，以及如何使用循环来显示玩家。

我已经尝试了几件事，但我不确定如何将它循环 X 次并显示它。

            Do
        If gamenum = 1 Or 3 Or 5 Then
            Console.WriteLine($"{vbCrLf}Enter player name.")
            player1 = Console.ReadLine
            Exit Do
        ElseIf gamenum = Nothing Then

            If gamenum = 2 Or 4 Or 6 Then
                Console.WriteLine($"{vbCrLf}Enter player names.")
                player1 = Console.ReadLine
                player2 = Console.ReadLine
            ElseIf gamenum = Nothing Then

                If gamenum = 7 Or 8 Or 9 Or 10 Then
                ElseIf gamenum = Nothing Then
                End If
            End If
        End If
    Loop
    Console.ReadKey()

Answer 1

这是执行此操作的一种方法。
使用列表存储所有玩家名称。

Dim players As New List(Of String) 'Stores all player names
Dim playerCount As Integer = 0     'Then number of players for this game

'Determine the required number of players based on gamenum
Select Case gamenum
    Case 1, 3, 5
        playerCount = 1
    Case 2, 4, 6
        playerCount = 2
    Case 7 To 10
        playerCount = 4
    Case Else
        Console.WriteLine("Invalid game choice!")
        Exit Sub
End Select

'Request players to enter their names
For i = 1 To playerCount
    Console.WriteLine($"{vbCrLf}Player {i}, enter your name")
    players.Add(Console.ReadLine)
Next

Console.WriteLine($"{vbCrLf}Total players registered: {players.Count}")

For i = 0 To players.Count - 1
    Console.WriteLine($"Welcome {players(i)}")
Next