XSLT：将 URL 查询字符串作为参数传递

Question

我知道这是一个老问题，已经传了好几次了，但我想知道是否有人可以扩展一个带有查询字符串的 URL 是否可以通过 XSLT 1.0 剥离并且可以用作供以后使用 XSLT 转换的参数。

例如，我的网址是http://www.mydomain.com/mypage.htm?param1=a&param2=b

通过 XSLT，我正在寻找类似以下内容的结果：

<xsl:param name="param1">a</xsl:param> 和<xsl:param name="param2">b</xsl:param>

参数名称 (param1, param2) 和它的值 (a, b) 都已从查询字符串中提取出来，以便我稍后在 if 条件中使用 $param1 和 $param2

例如<xsl:if test="$param1 = 'a'> 为真，但如果我们使用 <xsl:if test="$param1 = 'b'> 则为假。

我在这里看到了一个类似的问题：Retrieve page URL params or page URL in XSLT 它使用了str-split-to-words 模板，但我没有成功地让它工作（可能是因为我以错误的方式实现它）所以任何关于如何完成它的工作示例实践将大有裨益。

XSLT：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns="http://www.w3.org/1999/xhtml" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="http://exslt.org/common">
<xsl:import href="http://fxsl.cvs.sourceforge.net/viewvc/fxsl/fxsl-xslt2/f/strSplit-to-Words.xsl"/>
<xsl:output indent="yes" method="html"/>

<xsl:template match="/">
<xsl:variable name="vwordNodes">
  <xsl:call-template name="str-split-to-words">
    <xsl:with-param name="pStr" select="$pQString"/>
    <xsl:with-param name="pDelimiters" select="'?&amp;'"/>
  </xsl:call-template>
</xsl:variable>
<xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
</xsl:template>

<xsl:template match="word">
  <xsl:value-of select="."/>
  <xsl:text>&#xA;</xsl:text>
</xsl:template>

</xsl:stylesheet>

Answer 1

你的代码有几个问题：

1. <xsl:import href="http://fxsl.cvs.sourceforge.net/viewvc/fxsl/fxsl-xslt2/f/strSplit-to-Words.xsl"/> 我怀疑想要的样式表是否可以直接从其 SourceForge 视图页面导入——尤其是考虑到它本身会导入其他 FXSL 样式表。使用 FXSL 的正确方法是将其下载到本地计算机，并从其驻留在本地计算机的文件位置引用其样式表。

...

.2。 <xsl:with-param name="pStr" select="$pQString"/> 这将产生编译错误，因为您错过了定义 $pQString 全局/外部参数。您需要在全局级别定义此参数。它可以被赋予一个默认值（例如一个特定的 URL）以便于测试。但是，使用这个参数的想法是转换的调用者应该将这个参数传递给转换。

.3。转换的结果被写入输出。虽然这对于演示目的很有用，但您希望能够在稍后的转换中使用这些结果。这样做的方法是将这些结果捕获到一个变量中，从中创建另一个变量，使用常规树（来自其 RTF 类型），然后引用最后一个变量的节点。

这是您想要的代码示例（前提是您已经下载了 FXSL，解压缩了分发并将此代码保存在与解压缩的 FXSL 分发相同的目录中）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 >

   <xsl:import href="strSplit-to-Words.xsl"/>

   <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:param name="pUrl" select=
   "'http://www.mydomain.com/mypage.htm?param1=a&amp;param2=b'"/>

   <xsl:param name="pQString" select=
     "substring-after($pUrl, '?')"
     />


    <xsl:template match="/">
        <xsl:variable name="vwordNodes">
          <xsl:call-template name="str-split-to-words">
            <xsl:with-param name="pStr" select="$pQString"/>
            <xsl:with-param name="pDelimiters"
                      select="'?&amp;'"/>
          </xsl:call-template>
        </xsl:variable>

       <xsl:variable name="vrtfqueryParams">
         <xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
       </xsl:variable>

       <xsl:variable name="vqueryParams" select="ext:node-set($vrtfqueryParams)/*"/>

       <xsl:value-of select="$vqueryParams/@name[. ='param1']"/>
       <xsl:text> : </xsl:text>
       <xsl:value-of select="$vqueryParams[@name = 'param1']"/>

       <xsl:text>&#xA;</xsl:text>
       <xsl:value-of select="$vqueryParams/@name[. ='param2']"/>
       <xsl:text> : </xsl:text>
       <xsl:value-of select="$vqueryParams[@name = 'param2']"/>
    </xsl:template>

    <xsl:template match="word">
      <param name="{substring-before(.,'=')}">
        <xsl:value-of select="substring-after(.,'=')"/>
      </param>
    </xsl:template>
</xsl:stylesheet>

当此转换应用于任何 XML 文档（未在此演示中使用）时，将生成所需的正确结果——按名称引用结果变量的查询字符串参数：

param1 : a
param2 : b