数组中的最后一项未从循环内显示

Question

数组的最后一项不能从循环中正确打印

在学习 shell 文本过滤器时，我制作了一个小 awk 脚本，通过提供内联标题来格式化 CSV 文件的输出。

从命令行调用包装器 shell 脚本，它真正做的只是包装 awk 脚本并将参数作为变量 regex 传递，这是搜索字符串。

脚本将第一条记录 (NR==1) 的字段存储到数组 heading 中。在 CSV 文件的正文中找到包含搜索字符串 regex 的记录后，脚本会将标题连接到适当的值。

csv.sh：

#!/bin/bash

awk -f ~/Scripts/csv.awk -v "regex=$1" $2

csv.awk：

BEGIN {FS=",";}
NR==1 { 
  for (i=1; i<=NF; i++) { 
    heading[i]=$i; 
  } 
}
NR>1 {
  if ($0 ~ regex) {
    for (i=1; i<=length(heading); i++) {
      if(length($i) > 0) { 
        print(heading[i] ": " $i)
      } 
    }
    print("")
  }
}

演示

ships.csv：

name,country,displacement,length,beam,commissioned
Yamato,Japan,65027,256,38.9,16 December 1941
USS Enterprise,United States of America,19800,251.4,33.4,12 May 1938
Bismarck,Germany,41700,251,36,24 August 1940
HMS Dreadnought,United Kingdom,18120,160.6,25,2 December 1906
USS Iowa,United States of America,46000,270.43,32.97,22 February 1943
HMS Vanguard,United Kingdom,45200,248.2,32.9,12 May 1946

调用

$ csv Enterprise ships.csv

预期输出

name: USS Enterprise
country: United States of America
displacement: 19800
length: 251.4
beam: 33.4
commissioned: 12 May 1938

终端输出：

name: USS Enterprise
country: United States of America
displacement: 19800
length: 251.4
beam: 33.4
: 12 May 1938

在我的 Linux 计算机 (Manjaro) 上，输出非常相似。但实际上，如果我在我的 Mac 上将输出通过管道传输到 pbcopy，则标题在粘贴后会显示：

name: USS Enterprise
country: United States of America
displacement: 19800
length: 251.4
beam: 33.4
commissioned
: 12 May 1938

Answer 1

根据 Glenn 的评论，请您尝试关注一下。

awk 'BEGIN {FS=",";}
{gsub(/\r/,"")}
NR==1 { 
  for (i=1; i<=NF; i++) { 
    heading[i]=$i; 
  } 
}
NR>1 {
  if ($0 ~ regex) {
    for (i=1; i<=length(heading); i++) {
      if(length($i) > 0) { 
        print(heading[i] ": " $i)
      } 
    }
    print("")
  }
}'  Input_file

Answer 2

将数组传递给length 函数是less portable。

如果您怀疑一个混乱的 csv 文件，其中您的标题可能与实际列不匹配，那么，一个可移植的选项是在开始时存储总列的计数，然后像下面这样重复使用它：

NR==1 { 
  headercount=NF; # store the count
  for (i=1; i<=NF; i++) { 
    heading[i]=$i; 
  } 
}
NR>1 {
  if ($0 ~ regex) {
    for (i=1; i<=headercount; i++) { #Use the count
      if(length($i) > 0) {
        print(heading[i] ": " $i)
      }
    }
    print("")
  }
}

此外，如果您必须处理 dos 样式的文件结尾，您可以将脚本更改为：

#!/bin/bash
dos2unix -q "$2" # This makes sure that the input file has unix style file endings
awk -f ./csv.awk -v "regex=$1" $2

测试

$ ./csv.sh HMS ships.csv 
name: HMS Dreadnought
country: United Kingdom
displacement: 18120
length: 160.6
beam: 25
commissioned: 2 December 1906

name: HMS Vanguard
country: United Kingdom
displacement: 45200
length: 248.2
beam: 32.9
commissioned: 12 May 1946

如果您的标题被篡改，以至于它们没有委托列，那么这也可以在这种情况下无缝工作。

测试

$ ./csv.sh HMS ships.csv 
name: HMS Dreadnought
country: United Kingdom
displacement: 18120
length: 160.6
beam: 25

name: HMS Vanguard
country: United Kingdom
displacement: 45200
length: 248.2
beam: 32.9