【问题标题】:How to color the output of awk depending on a condition如何根据条件为 awk 的输出着色
【发布时间】:2015-02-18 22:25:21
【问题描述】:

我有一个包含以下内容的输入文件 test.txt:

 a 1 34
 f 2 1
 t 3 16
 g 4 11
 j 5 16

我使用 awk 只打印字符串 2 和 3:

awk '{print $2 " " $3}' test.txt

有没有办法根据条件只为我的输出的第二个字符串着色,如果值高于 15,则以橙色打印,如果值高于 20,则以红色打印。它会给出相同但有颜色的:

1 34(red)
2 1
3 16(orange)
4 11
5 16(orange)

输入可以包含更多不同顺序的行。

【问题讨论】:

  • 您是在询问如何为输出字符串着色或如何根据条件或两者兼而有之?
  • 我要求两者,如果值高于 15 则打印为橙色,如果高于 20 则打印为红色,低于 15 则正常打印。

标签: shell awk


【解决方案1】:

这个 awk 命令应该做你想做的事:

awk -v red="$(tput setaf 1)" -v yellow="$(tput setaf 3)" -v reset="$(tput sgr0)" '{printf "%s"OFS"%s%s%s\n", $1, ($3>20)?red:($3>15?yellow:""), $3, reset}'

这里的关键位是

  • 使用tput 来获得设置当前终端颜色的正确表示(而不是硬编码特定的转义序列)
  • 使用 -v 设置 awk 命令用于构造其输出的变量值

上面的脚本写得很简洁,但可以写得不那么简洁:

{
    printf "%s"OFS, $1
    if ($3 > 20) {
        printf "%s", red
    } else if ($3 > 15) {
        printf "%s", yellow
    }
    printf "%s%s\n", $3, reset
}

编辑:Ed Morton 正确地指出,上面的 awk 程序可以通过使用 color 变量并将颜色选择与打印分开来简化。像这样:

awk -v red="$(tput setaf 1)" -v yellow="$(tput setaf 3)" -v reset="$(tput sgr0)" \
'{
    if ($3>20) color=red; else if ($3>15) color=yellow; else color=""
    printf "%s %s%s%s\n", $1, color, $3, reset
}'

【讨论】:

  • +1 FWIW 我会发现 if ($3>20) color=red; else if ($3>15) color=yellow; else color=""; printf "%s %s%s%s\n", $1, color, $3, reset 更清晰...
  • @EdMorton 确实如此。我要把那件事归咎于“严格翻译”的盲目性。
  • 是的,它完成了这项工作,它很长,但我喜欢使用 tput,我使用它并且它完美,谢谢。
【解决方案2】:

您可以执行以下操作:

awk '{printf "%s ", $2}
     $3 > 15 {printf "\033[33m"}
     $3 > 20 {printf "\033[31m"}
     {printf "%s\033[0m\n", $3}' test.txt

很遗憾,我不知道橙色的ansi转义码……

另一种方法:

awk -v color1="\033[33m" -v color2="\033[31m" -v reset="\033[0m" '
     $3 > 15 && $3 <= 20 {$3=color1 $3 reset}
     $3 > 20 {$3=color2 $3 reset}
     {print $2, $3}' test.txt

【讨论】:

  • 我喜欢你的,因为它非常简单,很容易在管道之后添加,谢谢你的命令。
【解决方案3】:
awk '{if($2>15 && $2<=20){$2="\033[1;33m" $2 "\033[0m"};if($2>20){$2="\033[1;31m" $2 "\033[0m"};print}' file

细分

($2>15 && $2<=20){$2="\033[1;33m" $2 "\033[0m"}  # if field 2>15 and =<20, then add colour code to field 2.

if($2>20){$2="\033[1;31m" $2 "\033[0m"} ## if field 2>20, then add colour code to field 2.

print #print line afterwards

【讨论】:

  • 这个也不错,有趣的是不同的方式如何导致相同的结果。
猜你喜欢
  • 2019-11-12
  • 1970-01-01
  • 2017-06-03
  • 1970-01-01
  • 2022-01-10
  • 2021-02-20
  • 1970-01-01
  • 2021-09-05
  • 2020-01-11
相关资源
最近更新 更多