当条件为真时从另一个文件添加行

Question

继续链接Print rows with condition on field data中的问题

我有另一个包含数据的文件 2

cell   input  out  type   fun  level
CLK    C       Z    seq   Cq   1      
DFk    C,Cp    Q    seq   IQ   1
DFR    D,C     Qn   seq   IN   1
SKN    SE,Q    Qp   seq   Iq   1

下面的代码是获取级别总和为 7 并打印行。

awk '
function rnd(max) {        
   return int(rand()*max-1)+2
}
BEGIN {
   srand()                
}
NR == 1 {                  
   print                   
   next
}
{
   rec[NR] = $0           
   num[NR] = $NF           
}
END {
   while(1) {             
      r = rnd(NR)          
      if (!seen[r]++)      
         s += num[r]      

      if (s == 7)         
         break
      else if (s > 7) {   
         delete seen
         s = 0
         continue
      }
   }
   for (j in seen)         
      print rec[j]
} ' file1

上面的代码每次执行时只打印一组输出（level sum 7 true）。

但现在我想打印两组数据，当我执行一次代码时，当 level sum = 7 为真时，我想在新行中插入来自 file2 的行。

输出结果

cell   input     out    type      fun            level
AI20   A1,A2      Z     comb    ((A1A2))           2
INV    I1         ZN    comb    (!I1)              1  
BUF  A1,A2,A3,B1  Z     comb    (!(((A1A2)A3)B1))  4
CLK    C          Z     seq      Cq                1
XOR    A1,A2,B1   Z     comb    (((A1A2)B1)        3
IAD    A1,A2,A3   Z     comb    (!((A1A2)A3))      3
INV    I1         ZN    comb    (!I1)              1

在输出中，我们可以看到CLK C Z seq Cq 1 行是从 file2 插入的，而 file1 的级别总和为 7。

为了得到这个输出，我将上面的代码修改为

awk '
function rnd(max) {        
   return int(rand()*max-1)+2
}
BEGIN {
   srand()                
}
NR == 1 {                  
   print                   
   next
}
{
   rec[NR] = $0           
   num[NR] = $NF           
}
END {
   for (( i=1; i<3;i++)) 
     do  
         
      r = rnd(NR)          
      if (!seen[r]++)      
         s += num[r]      

      if (s == 7)         
         for line in $file2
           do
             awk '{ $0 }'
           done
     done

      else if (s > 7) {   
         delete seen
         s = 0
         continue
      }
   
   for (j in seen)         
      print rec[j]
} ' file1

但是从 file2 打印行时出现错误。

Answer 1

您可以使用这个增强的 awk 脚本：

cat rnd.awk

function rnd(max) {           # generate a randon number between 2 and max
   return int(rand()*max-1)+2
}
function rndsum() {
   while(1) {                 # infinite loop
      r = rnd(NR)             # generate a randomm number between 2 and NR
      if (!seen[r]++)         # populate seen array with this random number
         s += num[r]          # get aggregate sum from num array

      if (s == sum)           # if sum then break the loop
         break
      else if (s > sum) {     # if s > sum then restart the loop
         delete seen
         s = 0
         continue
      }
   }
   for (j in seen)            # for each val in seen print rec array
      print rec[j]
   delete seen
   s = 0
}
BEGIN {
   srand()                    # seed random generation
}
NR == 1 {                     # for header row
   print                      # print header record
   next
}
FNR == NR {                   # while processing file1
   rec[NR] = $0               # save each record in rec array with NR as key 
   num[NR] = $NF              # save last column in num array with NR as key
   next
}
FNR > 1 {
   rec2[++n] = $0             # records in file2 being saved in rec2
}
END {
   rc = rc > n ? n : rc       # allow rc to be max of row count in file2
   for (i=1; i<=rc; ++i) {    # for 1..rc
      rndsum()               # print random rows from file1
      print rec2[i]           # print a row from file2
   }
   rndsum()                  #  print random rows from file1
}

现在将其用作：

awk -v sum=7 -v rc=2 -f rnd.awk file1 file2 | column -t

cell  input        out  type  fun                level
IA2   A1,A2,A3     Z    comb  ((!A1A2)A3)        3
BUF   A1,A2,A3,B1  Z    comb  (!(((A1A2)A3)B1))  4
CLK   C            Z    seq   Cq                 1
IA2   A1,A2,A3     Z    comb  ((!A1A2)A3)        3
IAD   A1,A2,A3     Z    comb  (!((A1A2)A3))      3
INV   I1           ZN   comb  (!I1)              1
DFk   C,Cp         Q    seq   IQ                 1
XOR   A1,A2,B1     Z    comb  (((A1A2)B1)        3
IAD   A1,A2,A3     Z    comb  (!((A1A2)A3))      3
INV   I1           ZN   comb  (!I1)              1

又一次：

awk -v sum=7 -v rc=1 -f rnd.awk file1 file2 | column -t

cell  input        out  type  fun                level
IAD   A1,A2,A3     Z    comb  (!((A1A2)A3))      3
BUF   A1,A2,A3,B1  Z    comb  (!(((A1A2)A3)B1))  4
CLK   C            Z    seq   Cq                 1
XOR   A1,A2,B1     Z    comb  (((A1A2)B1)        3
BUF   A1,A2,A3,B1  Z    comb  (!(((A1A2)A3)B1))  4