Perl 无法统计 $_

Question

我想要目录中每个文件的最后修改时间。为了确保我的循环正常工作，我打印 $_ 并看到目录的文件名：

for ( @Files ) {

    opendir( D, $path . '\/' . $_ ) or die "$!";
    my @textfiles = grep { ! /^\.{1,2}$/ } readdir( D );

    for ( @textfiles ) {

        #    print "$_\n";   <----the file names.
        my $epoch_timestamp = ( stat( $_ ) )[9];
        print "$epoch_timestamp\n";
    }

我收到此错误

在连接 (.) 或字符串中使用未初始化的值 $epoch_timestamp

我做错了什么？

Answer 1

readdir 仅返回文件名。如果您当前的工作目录不同，那么您必须像使用 opendir 的参数一样构建完整路径。最简单的方法是在for 循环的列表中使用map

我很担心你的说法

opendir( D, $path . '\/' . $_ ) or die "$!";

从字面上看，这会将\/ 置于$path 和$_ 之间。我认为您只需要/，但使用

插入变量是最简单的

opendir( D, "$path/$_" ) or die "$!";

但是$_ 来自数组@Files。如果这些确实是文件名，那么您的 opendir 将失败。它们需要是目录名称

在我的解决方案中，我将变量 $dir 构建为

my $dir = "$path/$_"

以便它可以用于调用opendir 以及在以下for 循环中构建文件的完整路径

请注意，我还使用了词汇目录句柄my $dh，它远远优于全局句柄D

for ( @Files ) {

    my $dir = "$path/$_";

    opendir my $dh, $dir or die $!;
    my @textfiles = grep { ! /^\.{1,2}$/ } readdir $dh;

    for ( map { "$dir/$_" } @textfiles ) {

        #    print "$_\n";   <----the file names.
        my $epoch_timestamp = ( stat( $_ ) )[9];

        print "$epoch_timestamp\n";
    }

Answer 2

或者，除了上述完美答案之外，您还可以使用一些模块，让您的生活更轻松。 :) 喜欢：Path::Tiny^[1]

use 5.014;
use warnings;

use Path::Tiny;

my $path = path('/etc');
my @Files = qw(defaults cups ssl);

for my $dir (@Files) {
    my @textfiles = $path->child($dir)->children;
    for my $file (@textfiles) {
        say "$file: ", $file->stat->mtime;
    }
}

当然，上面的嵌套循环可以写成

for my $dir (@Files) {
    my @textfiles = $path->child($dir)->children;
    say "$_: ", $_->stat->mtime for (@textfiles);
}

也不需要将文件列表存储到@textfiles，因此可以简化为：

for my $dir (@Files) {
    say "$_: ", $_->stat->mtime for ( $path->child($dir)->children );
}

---

1. Path::Tiny 在出错时方便地抛出一个干净的异常消息。

Answer 3

readdir 只返回目录中文件的名称。您需要向stat 提供文件的限定路径。

my $dir_qfn = ...;
opendir(my $dh, $dir_qfn)
    or do {
        warn("Can't read dir \"$dir_qfn\": $!\n");
        next;
    };

while (defined( my $fn = readdir($dh) )) {
   next if $fn =~ /^\.\.?\z/;

   my $qfn = "$dir_qfn/$fn";
   my $mtime = ( stat($qfn) )[9];
   defined($mtime)
       or do {
           warn("Can't stat file \"$file_qfn\": $!\n");
           next;
       };

   ...
}

Answer 4

改用glob

my $dir = ...;

my %ts =
    map { $_ => (stat $_)[9] }
        grep { !m{/\.\.?\z} }    #/
            glob "\Q$dir\E/{*,.*}";

say "ts{$_} => $_" for sort keys %ts;

我使用散列 name => timestamp 在数据结构中收集两者。模式$dir/{*,.*} 也用于捕获点文件，或者它只是$dir/*。

grep 过滤掉. 和.. 文件名，在m{..} 匹配的路径中找到。它的模式需要\Q..\E 来防止具有特定目录名称的注入错误。它还可以转义空格，因此不需要带有:bsd_glob选项的File::Glob。感谢ikegami cmets。

如果您希望一次处理一个文件，请使用glob 检索列表，然后遍历它。