在部分单元格文本中查找单词，返回列号：Excel VBA

Question

我的目标是在 Excel 的用户表单中实现搜索功能。

它应该能够获取在TextBox 中输入的单词并遍历特定行中的每一列并搜索该单词。然后它应该返回第一次发现它的列。

使用下面的代码，它只会查看与单元格内容完全匹配的内容。但是，如果单元格值是例如：“Lorem ipsum，dolor sitamet” - 我希望能够搜索“dolor”。

这是我的代码：

Dim rFind As Range     
With Range("D1:D100")
    Set rFind = .Find(What:=TextBox13.Value, LookAt:=xlWhole, MatchCase:=False, SearchFormat:=False)
    If Not rFind Is Nothing Then
        MsgBox rFind.Column
        MsgBox rFind.Row
    End If
End With

Answer 1

只需将LookAt:=xlWhole 更改为LookAt:=xlPart

文档：Range.Find Method (Excel)

---

您也可以使用 & 符号 (&) 来整理返回的结果，它连接字符串：

"Col: " & rFind.Column & ", Row: " & rFind.Row
' For example, gives the string "Col: 1, Row: 1" if found in A1

您说您要在“特定行中的每一列”中进行搜索，但您正在查看“特定列中的前 100 行”？！不确定这是拼写错误还是您的代码错误。无论哪种方式，您都可以使用 Rows 或 Columns 对象。这些应该与您的范围完全限定一起使用，即说明它在哪里。

ThisWorkbook.Sheets("Sheet1").Rows(1)      ' Range of entire first row
ThisWorkbook.Sheets("Sheet1").Columns(1)   ' Range of entire first column
ThisWorkbook.Sheets("Sheet1").Columns("A") ' Equivalent, range of entire first column

重写：

Dim rFind As Range     
With ThisWorkbook.Sheets("Sheet1").Columns("D")
    Set rFind = .Find(What:=TextBox13.Value, LookAt:=xlPart, MatchCase:=False, SearchFormat:=False)
    If Not rFind Is Nothing Then
        MsgBox "Col: " & rFind.Column & ", Row: " & rFind.Row
    End If
End With

Answer 2

部分

LookAt:=xlWhole

应该是

LookAt:=xlPart

Answer 3

看起来你想检查每个单词 - 这会做到这一点：

Sub Check()
Dim vWords As Variant
Dim sCheck As String
Dim rFind As Range
Dim i As Long

sCheck = "Lorem ipsum, dolor sitamet" ' TextBox13.Value
sCheck = Replace(sCheck, ",", "")

vWords = Split(sCheck, " ")

For i = 0 To UBound(vWords)
    With Range("D1:D100")
        Set rFind = .Find(What:=Trim(vWords(i)), LookAt:=xlPart, MatchCase:=False, SearchFormat:=False)
        If Not rFind Is Nothing Then
            MsgBox rFind.Column
            MsgBox rFind.Row
        End If
        Set rFind = Nothing
    End With
Next

End Sub

Answer 4

代码更新：对于所有 cmets， 1.增加了xlPart 2. 只执行了一次搜索，

现在，如果你能升级我。

最简单的代码 - 根据您选择的范围 - Range("D1:D100")，您只能找到值存在的行号。为了也能找到列号，请扩大您的范围。

就是这样-

Sub find_code()
Dim add As String

On Error Resume Next
add = Range("D1:D100").Find(TextBox1.Text, Lookat:=xlPart, MatchCase:=False).AddressLocal

If Err.Number <> 0 Then
MsgBox "Empty Search result", vbInformation
Exit Sub
End If

MsgBox Range(add).Row
MsgBox Range(add).Column

End Sub