用从表中读取的 perl 脚本替换单词（以匿名化名称）

Question

我正在寻找一种用 perl 替换大文本中的单词的方法，并希望从另一个包含替换的文件中读取这些单词。我知道我能做到：

#!/usr/bin/perl

use warnings;
use strict;

open my $fh_in, '<', $ARGV[0] or die "No input: $!";
open my $fh_out, '>', $ARGV[1] or die "No output: $!";

while (<$fh_in>) 
{
    s/John/Jack/g;

    print $fh_out $_;
}   

... 并放置任意数量的 s/Fred/Frank/g; 行。 是否可以引用包含所有替换的外部文本文件？这是为了在采访中匿名化姓名。

我正在考虑以以下格式保存一个简单的文本文件：

Name    Pseudonym   
John    Jack  
Fred    Frank  
etc.

（以制表符分隔）
如果有更好的方法可以做到这一点，我会感谢您的建议。 原件来自一个 Excel 数据库，该数据库在两列中包含所有名称替换，但将其放入文本文件相当容易，而且我不想让它太复杂，因为我对脚本和东西不太熟悉。

Answer 1

读取包含哈希对应的文件，然后像这样进行替换：

#!/usr/bin/perl

use warnings;
use strict;

open my $fh_in, '<', $ARGV[0] or die "No input: $!";
open my $fh_out, '>', $ARGV[1] or die "No output: $!";

open my $fh_pseudo, '<', "path/to/pseudo" or die "unable to open pseudo: $!";
my %corres;
while (<$fh_pseudo>) {
    chomp;
    my ($name, $pseudo) = split /\t/, $_;
    $corres{$name} = $pseudo if $name && $pseudo;
}

while (my $line = <$fh_in>) {
    $line =~ s/\b$_\b/$corres{$_}/g for keys %corres;
    print $fh_out $line;
}   

Answer 2

如果您阅读文件的所有内容，您将在内存中执行替换之前进行替换会更容易。

您还应该注意不要替换特定的子字符串。如果您有输入文件：“Hello Fred”。在替换列表“Fred Frank”和“Frank Frankstein”中，您最终会得到“Hello Frankstein”...

我将替换列表放在 DATA 部分下，以使其独立。

use strict;                                                                      
use warnings;                                                                    
use utf8;                                                                        
use IO::All;                                                                        

my %list;                                                                        

die "File not found or can't be read\n"                                          
unless $ARGV[0] && -e $ARGV[0] && -r $ARGV[0];                                 

die "Need an output file name\n" unless $ARGV[1];                                
my $output = $ARGV[1];                                                           

while (<DATA>) {                                                                 
    my ( $name, $nick ) = m/(\w+)\t(\w+)$/;                                      
    next unless $name && $nick;                                                  
    $list{$name} = $nick;                                                        
}                                                                                   

my $contents = io->file($ARGV[0])->slurp;                                           

for my $name ( keys %list ) {                                                    
    $contents =~ s/\b$name\b/$list{$name}/g;                                         
}                                                                                

$contents > io($output);                                                         

__DATA__                                                                         

John    Jack                                                                     
Fred    Frank