是否可以指定要替换的最大匹配数。例如，如果匹配“Hello World”中的 'l'，是否可以替换前 2 个 'l' 字符，但不能替换第三个而不循环？
【问题讨论】：
re.sub(repl, string[, count=0])，但这显然不是你想要的。
$str = "Hello world!";
$str =~ s/l/r/ for (1,2);
print $str;
我看不出循环有什么不好。
其实有一个办法：
$str="Hello world!";
$str =~ s/l/$i++ >= 2 ? "l": "r"/eg;
print $str;
这是一个循环，因为 s///g 在您执行此操作时会以循环方式工作。但不是传统的循环。
【讨论】：
while (/match/g) 来创建一个循环。
这是一种方法。这需要使用(?(condition)true-sub-expression|false-sub-expression) 构造内的(?{code}) 块在RE 内更新外部计数器。请参阅perldoc perlre 了解说明。
use Modern::Perl;
use re qw/eval/; # Considered experimental.
my $string = 'Hello world!';
my $count = 2;
my $re = qr/
(l)
(?(?{$count--})|(*FAIL))
/x;
say "Looking for $count instances of 'l' in $string.";
my ( @found ) = $string =~ m/$re/g;
say "Found ", scalar @found, " instances of 'l': @found";
输出是：
Looking for 2 instances of 'l' in Hello world!
Found 2 instances of 'l': l l
这是对相同正则表达式的另一个测试，但这次我们跟踪匹配项的位置只是为了证明它与前两次匹配。
use Modern::Perl;
use strict;
use warnings;
use re qw/eval/; # Considered experimental.
my $string = 'Hello world!';
my $count = 2;
my $position = 0;
my $re = qr/
(l)(?{$position=pos})
(?(?{$count--})|(*FAIL))
/x;
while( $string =~ m/$re/g ) {
say "Found $1 at ", $position;
}
而这次的输出是：
Found l at 3
Found l at 4
我不认为我会推荐这些。如果我正在考虑将匹配限制在字符串的一部分，我会匹配字符串的substr()。但是，如果您喜欢生活在边缘，请继续享受这个 sn-p 的乐趣。
这里是替换：
use Modern::Perl;
use strict;
use warnings;
use re qw/eval/; # Considered experimental.
my $string = 'Hello world!';
say "Before substitution $string";
my $count = 2;
my $re = qr/
(l)
(?(?{$count--})|(*FAIL))
/x;
$string =~ s/$re/L/g;
say "After substitution $string";
还有输出：
Before substitution Hello world!
After substitution HeLLo world!
【讨论】：
简短的回答：不。您将需要在某种循环中执行替换。
【讨论】：
@re = qw(l l); s/(l)/shift @re || $1/eg;