使用 .bat 文件运行/杀死可执行文件

Question

批处理文件脚本对我来说是全新的，所以请耐心等待...

为了在 Windows（10、64 位）环境中运行许多（例如 5076）计算，我使用.bat 文件：

gulp.exe < input-1.dat > output-1.out
gulp.exe < input-2.dat > output-2.out
gulp.exe < input-3.dat > output-3.out
                 .
                 .
                 .
gulp.exe < input-5076.dat > output-5076.out

不幸的是，一些计算将挂起（原因不明）...目前，当这种情况发生时，我手动终止整个批处理命令...这意味着我必须密切关注计算的进展情况并且不能简单地让它们运行（例如过夜）

因此，如果 gulp.exe 可执行文件已经运行了 30 分钟，我正在寻找一种自动杀死它的方法，但是这意味着我的列表中的下一个计算仍在运行。
即如果计算 2 挂起，杀死它并运行计算 3

搜索 [1, 2] 表示taskkill 可能是我正在寻找的命令，但对于它是否会杀死 .bat 脚本或可执行文件以及如何将其应用于列表中的多个计算有点困惑。

因此，我真的很感激一些指针...... 谢谢

Answer 1

计算会消耗 CPU 时间，因此您可以使用内置的 typeperf 在 1 秒内进行分析，假设一次只能运行一个 GULP 进程。

@echo off

set INTERVAL=1
set CPUTHRESHOLD=0.1

call :runGulp "input-1.dat" "output-1.out"
call :runGulp "input-2.dat" "output-2.out"
call :runGulp "input-3.dat" "output-3.out"

pause
exit /b

:runGulp
    start /b gulp <"%~1" >"%~2"
    :wait
        for /f "delims=, tokens=2 skip=2" %%a in ('
            typeperf "\Process(GULP)\%% Processor Time" -si %INTERVAL% -sc 1
        ') do (
            if %%~a GEQ %CPUTHRESHOLD% goto wait
            if %%~a==-1 exit /b
        )
    taskkill /f /im gulp.exe
    exit /b