用许多 <xsl:when> 优化 <xsl:choose>

Question

我有一系列中等大小的XML文档，主要是文本，有几个节点代表要扩展的宏，例如：

<foo>Some text <macro>A1</macro> ... <macro>B2</macro> ...etc...</foo>

我的目标是用相应的 XML 替换每个宏。通常它是一个具有不同属性的<img> 标签，但也可以是其他一些 HTML。

样式表是以编程方式生成的，一种方法是为每个宏设置一个模板，例如

<xsl:template match="macro[.='A1']">
    <!-- content goes here -->
</xsl:template>
<xsl:template match="macro[.='A2']">
    <!-- other content goes here -->
</xsl:template>
<xsl:template match="macro[.='B2']">
    <!-- etc... -->
</xsl:template>

它工作得很好，但它最多可以有一百个宏，而且性能不是很好（我正在使用 libxslt。）我尝试了几种替代方法，例如：

<xsl:template match="macro">
    <xsl:choose>
        <xsl:when test=".='A1'">
            <!-- content goes here -->
        </xsl:when>
        <xsl:when test=".='A2'">
            <!-- other content goes here -->
        </xsl:when>
        <xsl:when test=".='B2'">
            <!-- etc... -->
        </xsl:when>
    </xsl:choose>
</xsl:template>

它的性能略高一些。我尝试添加另一个级别的分支，例如：

<xsl:template match="macro">
    <xsl:choose>
        <xsl:when test="substring(.,1,1) = 'A'">
            <xsl:choose>
                <xsl:when test=".='A1'">
                    <!-- content goes here -->
                </xsl:when>
                <xsl:when test=".='A2'">
                    <!-- other content goes here -->
                </xsl:when>
            </xsl:choose>
        </xsl:when>
        <xsl:when test=".='B2'">
            <!-- etc... -->
        </xsl:when>
    </xsl:choose>
</xsl:template>

它的加载速度稍慢（XSL 更大且更复杂），但执行速度稍快（每个分支可以消除几种情况。）

现在我想知道，有没有更好的方法来做到这一点？我有大约 50-100 个宏。通常，转换是使用 libxslt 执行的，但我不能使用来自其他 XSLT 引擎的专有扩展。

欢迎任何意见:)

Answer 1

这将是另一种方式：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl">
    <xsl:variable name="dummy">
            <mac id="A1">success</mac>
            <mac id="A2">fail</mac>
            <mac id="B1">This <b>fail</b></mac>
            <mac id="B2">This <b>success</b></mac>
    </xsl:variable>
    <xsl:key name="macro" match="mac" use="@id"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="macro">
        <xsl:variable name="me" select="."/>
        <xsl:for-each select="document('')">
            <xsl:copy-of select="key('macro',$me)/node()"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

注意：这是性能：XML parse 1,805ms, XSL parse 0,483ms, Transform 0,215ms

Answer 2

如果您的宏是固定的 XML，您可以有一个类似于以下内容的 macros.xml 文档：

<?xml version="1.0"?>
<macros>
    <macro name="A1"><!-- content goes here --></macro>
    <macro name="A2"><!-- content goes here --></macro>
</macros>

然后您可以：

<xsl:template match="macro">
    <xsl:variable name="name" select="text()"/>
    <xsl:apply-templates select="document(macros.xml)/macros/macro[@name=$name]" mode="copy"/>
</xsl:template>

<xsl:template match="*" mode="copy">
    <xsl:copy><xsl:copy-of select="*"/>
        <xsl:apply-templates mode="copy"/>
    </xsl:copy>
</xsl:template>

这会提高性能吗？

Answer 3

尝试将所有macro处理提取到单独的模板模式中，并且只对macro元素的内容运行它。即：

<xsl:template match="macro">
   <xsl:apply-templates mode="macro"/>
</xsl:template>

<xsl:temlate match="text()[. = 'A1']" mode="macro">
   ...
</xsl:template>

我怀疑您的情况放缓是因为您的规则会针对输入中的每个节点逐一检查。这样，您可以检查它是否为 macro，并且只有当它是时，它的内容才会进一步匹配。