如何重命名运行 mnesia 数据库的节点答案

【问题标题】：How to rename the Node running a mnesia Database如何重命名运行 mnesia 数据库的节点
【发布时间】：2010-10-02 13:55:48
【问题描述】：

我在 machine1 上创建了一个 Mnesia 数据库/模式。该节点被命名为 mypl@machine1。然后我将所有文件移动到 machine2，因为 machine1 发生故障。只要代码以“mypl@machine1”的名称运行，一切都运行良好。显然这有点令人困惑，因为它现在在 machine2 上运行。

如果我使用节点名称“mypl@machine2”启动 Erlang，Mnesia 数据库将显示为空。

如何将 Mnesia 数据库中的节点从 machine1 重命名为 machine2？

【问题讨论】：

标签： erlang mnesia

【解决方案1】：

我认为这不能在单个节点上在线完成（任何人？），但除了运行两个节点和添加表副本之外，还可以通过备份/恢复来完成。在Mnesia User's guide 6.9.1 节中，您会发现一些代码使用 mnesia:traverse_backup 在 mnesia 备份文件中更改模式表（如下所示）中的节点名称。您可能应该使用的模块名称是mnesia_backup。

使用此代码，您需要：

%% On mypl@machine1
mnesia:backup("/path/to/mnesia.backup").
change_node_name(mnesia_backup, mypl@machine1, mypl@machine2,
                 "/path/to/mnesia.backup", "/path/to/new.mnesia.backup").
%% On mypl@machine2
mnesia:restore("/path/to/new.mnesia.backup", []).

我不确定您是否需要先在 mypl@machine2 上创建架构。

用户指南中的更改节点名称代码：

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).

【讨论】：

我按照以下步骤操作但恢复失败，有什么建议吗？ 1.备份原数据库 2.更改节点名称 3.将bak复制到另一台机器 4.恢复新的备份文件错误信息为：{aborted,{'EXIT',{aborted,{bad_commit,{missing_lock,'web_server @anothernode'}}}}}

【解决方案2】：

解决方法是迁移。只需启动 mnesia 集群并将所有表和模式迁移到其他节点。比从原来的删除和忘记。

【讨论】：